上一篇：

批处理去掉网吧、电竞酒店系统Win11快捷键方式小箭头代码，注意避坑「该文件没有与之关联的应用程序来执行该操作」

本篇需求：

给系统的CMD加密，需要密码才能进入CMD。

完整代码：

@echo off
if exist %windir%\fly.bat attrib -a -s -r -h %windir%\fly.bat
cls
title CMD 密码设置
echo ================================================================================
echo                                 CMD 密码设置
echo.
echo                               默认密码为:123456 
echo.
echo                 如需更改请在下面输入你的密码,不更改直接回车.........
echo.
echo ================================================================================
set paa=
set /p paa=请输入你的新密码:
if not defined paa call :paa
reg add "HKLM\SOFTWARE\Microsoft\Command Processor" /v AutoRun /t REG_SZ /d %windir%\fly.bat /f >nul
echo ^@echo off >%windir%\fly.bat
echo ^cls >>%windir%\fly.bat
echo title CMD-Dos 验证............. >>%windir%\fly.bat
echo set n=3 >>%windir%\fly.bat
echo ^:start >>%windir%\fly.bat
echo ^cls >>%windir%\fly.bat
echo echo                            CMD-DOS地带 >>%windir%\fly.bat
echo echo. >>%windir%\fly.bat
echo set pa= >>%windir%\fly.bat
echo set /p pa=请输入密码: >>%windir%\fly.bat
echo if /i "%%pa%%"=="%paa%" goto ok >>%windir%\fly.bat
echo set /a n-=1 >>%windir%\fly.bat
echo if "%%n%%"=="0" echo               密码错误...你没机会咯...^&ping 127.1 -n 2 ^>nul^&exit >>%windir%\fly.bat
echo echo                     密码错误..你还有%%n%%机会^&ping 127.1 -n 2 ^>nul >>%windir%\fly.bat
echo goto start >>%windir%\fly.bat
echo ^:ok >>%windir%\fly.bat
echo ^cls >>%windir%\fly.bat
echo title 你可以正常使用 CMD-Dos ............. >>%windir%\fly.bat
echo echo                              欢迎进了CMD-DOS地带 >>%windir%\fly.bat
echo cd /d c: >>%windir%\fly.bat
:stt
if not exist %windir%\fly.bat goto stt
attrib +a +s +r +h %windir%\fly.bat
cls
echo.
echo.
echo                      设置完毕.............你的密码为:%paa%
echo.
gpupdate /force >nul 
echo 任意键退出....
pause>nul
exit

:paa
echo 你没有设置密码..现起用默认密码..........
set paa=123456
goto :eof

执行效果：

测试发现，开始->运行->输入cmd后会提示需要密码，密码错误后无法进入CMD模式。

总结：

这种方法比较简单，也比较容易被破解，但是用来学习批处理源码还是挺有意义的，可以学习到批处理添加注册表和动态生成批处理并运行的代码写法。