网吧管理经验---高效的运用.vbs .bat 管理...

首先应该建立管理"后门"--在组策略里边添加登陆脚本...

然后开启我们的远程WMI,远程WSH...

好的我们的管理就此开始,首先的管理后门登陆脚本我们要做到万无一失.我采取的方案是 建立两个方案 从远程服务器下载脚本然后运行,默认为1号方案,如果1号方案的主机不通,就采取2号方案的主机.如果都不通(那没有办法了,没有错误处理)系统会报错

然后我们建立远程WMI,远程WSH,做到想查看哪个机器就查看哪个机器...好的理论就是这样的.如下是我用的脚本和配置远程的方法(仅适合网吧所有机器的同Ghost镜像,否则没有权限)

Untitle.vbs

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'''''''''''''''''''''''''''''''''''''''''''''''''''''''时间:2008.02.15 PM17.01
'''''''''''''''''''''''''''''''''''''''''''''''''''''''作者:YuNalone''''''''''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'''''''''通过xml文件的配置,将远程文件夹(srcPath)中的文件复制到本地(desFile)'''
'''''''''然后执行复制到本地的文件(desFile),来做到对本地的配置'''''''''''''''''
'''''''''主要用于网吧'''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'''''''''简单版本,只有复制,运行,以及解析特定的xml节点'''''''''''''''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'''''''''不提供针对xml文件的错误预警,及处理机制.使用时请先进行测试''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'''''''''xml文件提供两套方案,默认为scheme.one方案'''''''''''''''''''''''''''''
'''''''''仅使用简单的判断机制(Ping 远程服务器),来更改方案'''''''''''''''''''''
'''''''''所以请确保远程服务器的共享文件的存在'''''''''''''''''''''''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'''''''''默认xml文件名为Untitled.xml,且默认与该脚本同一目录'''''''''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Option Explicit

Dim xml_AiQ
Dim srcIp,srcPath
Dim desPath,desFile
Dim sleepTime

Const xmlName = "Untitled.xml"

Set xml_AiQ = CreateObject("msxml2.DOMDocument.3.0")
xml_AiQ.load xmlName

main()

Set xml_AiQ = Nothing
WScript.Quit

Function AccessXml_AiQ(SchemeName,NodeName)

Dim NodeTemp
Dim str
str = "//scheme/" & SchemeName & "/" & NodeName
Set NodeTemp = xml_AiQ.selectSingleNode(str)
AccessXml_AiQ = NodeTemp.text
Set NodeTemp = Nothing

End Function

Function SelectScheme_AiQ()

Dim objWMIService,colPings
Dim objStatus
Dim strComputer

strComputer = "."

Set objWMIService = GetObject(_
    "winmgmts:\\" & strComputer & "\root\cimv2")
Set colPings = objWMIService.ExecQuery _
    ("Select * From Win32_PingStatus where Address = '" & srcIp & "'")

For Each objStatus in colPings
    If IsNull(objStatus.StatusCode) _
        or objStatus.StatusCode <> 0 Then
        Initialize_AiQ("scheme.two")
        SelectScheme_AiQ = "two"
        Exit Function
    End If
Next

SelectScheme_AiQ = "one"
Set colPings = Nothing
Set objWMIService = Nothing

End Function

Sub CopyFile_AiQ()
Dim fso

Set fso = CreateObject("Scripting.FileSystemObject")

If Not fso.FolderExists(desPath) Then fso.CreateFolder(desPath)
srcPath = srcPath & "\*.*"
fso.CopyFile srcPath,desPath
WScript.Sleep(sleepTime)
If Not fso.FileExists(desFile) Then fso.CopyFile srcPath,desPath

Set fso = Nothing
End Sub

Sub Initialize_AiQ(SchemeName)

Select Case SchemeName
   Case "scheme.one"
    srcIp = AccessXml_AiQ(SchemeName,"src.ip")
    srcPath = "\\" & srcIp & AccessXml_AiQ(SchemeName,"src.path")
    desPath = AccessXml_AiQ(SchemeName,"des.path")
    desFile = desPath & AccessXml_AiQ(SchemeName,"first.script")
    sleepTime = AccessXml_AiQ(SchemeName,"timeout")
   Case "scheme.two"
    srcIp = AccessXml_AiQ(SchemeName,"src.ip")
    srcPath = "\\" & srcIp & AccessXml_AiQ(SchemeName,"src.path")
    desPath = AccessXml_AiQ(SchemeName,"des.path")
    desFile = desPath & AccessXml_AiQ(SchemeName,"first.script")
    sleepTime = AccessXml_AiQ(SchemeName,"timeout")
End Select

End Sub

Sub Run_AiQ()

Dim wshll

Set wshll = CreateObject("Wscript.Shell")
wshll.Run desFile
Set wshll = Nothing

End Sub

Sub main()
Initialize_AiQ("scheme.one")
SelectScheme_AiQ()
CopyFile_AiQ()
Run_AiQ()
End Sub

Untitled.xml

<?xml version="1.0" encoding="gb18030" ?>

<scheme>
<scheme.one>
   <version>1.0</version>
   <src.ip>192.168.0.254</src.ip>
   <src.path>\ghost\system</src.path>
   <des.path>c:\script\</des.path>
   <first.script>first.vbs</first.script>
   <timeout>3000</timeout>
</scheme.one>

<scheme.two>
   <version>1.0</version>
   <src.ip>192.168.0.254</src.ip>
   <src.path>\ghost\system</src.path>
   <des.path>c:\script\</des.path>
   <first.script>first.vbs</first.script>
   <timeout>3000</timeout>
</scheme.two>
</scheme>

远程WMI

权限设置:

计算机管理--服务和应用程序--WMI 控件--属性--安全 对权限进行安全设置

本地策略--安全选项--DCOM:...访问权限 & DCOM:...驱动权限 & 网络访问:...共享和安全模式 & 帐户:...控制台登陆

组件服务--计算机--我的电脑--"配置"我的电脑--COM安全--编辑权限 & 编辑权限

远程帐户的密码...本地帐户存储的网络密码

并未进行测试,我的计算机已经被改过的...

远程WSH

1.HKEY_LOCAL_ MACHINE\SOFTWARE\Microsoft\Windows Script Host\Settings
添加 字符串 Remote 值为1
2.wscript -regserver
3.本地安全策略里边 网络访问:本地帐户的共享和安全模式 经典-本地用户以自己的身份验证
4.帐户:使用空白密码的本地帐户只允许进行控制台登陆 已停用

注意:

1.2步骤在本地以及远程系统均须
测试主机为2台Windows Xp Sp2. 远程计算机 仅有一系统默认的管理员帐户 无密码 无来宾

同时测试主机无网络密码(用户帐户存储的网络密码)--在测试中无作用,但感觉...

通过测试

欢迎访问最专业的网吧论坛,无盘论坛,网吧经营,网咖管理,网吧专业论坛 https://bbs.txwb.com 关注天下网吧微信/下载天下网吧APP/天下网吧小程序，一起来超精彩